TweetFollow Us on Twitter

DA Prototype
Volume Number:2
Issue Number:1
Column Tag:Pascal Procedures

Prototyping Desk Accessories

By Alan Wootton, President, Top-Notch Productions, MacTutor Contributing Editor

This month I will try to provide an interesting explanation of how to program Desk Accessories. Rather than simply attempting to explain the purpose and function of each of the three main procedures used by DA's (which has, after all, been done), we will try an entirely different approach. We will start with a simple DA, and take for granted the fact that it works. We will then type this DA's code into MacPascal and attempt to get it to run. In the process we will learn a lot about DA's, and when it is all done we will have a useful tool for prototyping Desk Accessories.

Perhaps at this point you are wondering "What do you mean, type it in and get it to run?" We can't make the system call a MacPascal procedure the same way it calls compiled 68000 procedures, so we will write a program that attempts to duplicate the actions of the system and its relationship with DA's. [ A desk accessory simulator! -Ed.]

To start with let's take a look at the DA we will be using as a subject. Its' code is listed below. Look at it briefly and then continue reading the text that follows.

The Simple DA We Will Be Using

 procedure UpdateSelf (var device : deviceControlRec);
 begin
    with device do
 begin
     SetPort(dctlWindow);
     BeginUpdate(dctlWindow);
 
 MoveTo(10, 30);
 DrawString('This is a test DA');
 
     EndUpdate(dctlWindow);
 end;{ of with }
 end;{ of UpdateSelf }

 procedure Open (var device : deviceControlRec;
                                           var block : ParamBlockRec);
     var
  R : Rect;
  wP : windowPeek;
 begin
     with device do
  begin
      setrect(R, 128, 128, 256, 256);
      dctlWindow := 
                  NewWindow(nil, R, 'Test DA', true, 0, nil, true, 0);
      wP := pointer(ord(dctlWindow));
      wP^.windowKind := dctlRefNum;
  end;{ of with }
 end;{ of open }

procedure  Close (var device : deviceControlRec;
                                            var block : ParamBlockRec);
 begin
     with device do
  begin
      DisposeWindow(dctlWindow);
      dctlWindow := nil;
  end;{ of with }
 end;{ of close }

 procedure Event (var device : deviceControlRec;
                                        var block : ParamBlockRec);
     var
         EventP : ^EventRecord;
 begin
    {  csParam holds a pointer to the event record }
    {  copy it to EventP }
     BlockMove(@block.csParam[0], @EventP, 4);
     with EventP^ do{ eventRecord    }
  begin
      case what of
  1 :           { mdown event }
      SysBeep(1);
  6 :            { update event }
      UpdateSelf(device);
  otherwise
      ;       { ignore all other events }
      end;{ case of what }
  end;{ with }
 end;{ procedure event }

 procedure Ctl (var device : deviceControlRec;
                                      var block : ParamBlockRec);
     var
  poi : point;
 begin
     setport(device.dctlWindow);
     with block do
  begin
      case csCode of
  64 :        { accEvent }
      Event(device, block);
  otherwise
      ;
     {        other codes (accRun, accCursor, accMenu,  
                          accCut, etc.) }
     {        are not used by this DA          }
      end;{ case of code }
  end;{ of with block }
 end;{ of Ctl  }

The first thing to notice about this DA is that it does practically nothing. The Open procedure creates a window, the Ctl procedure only handles calls of type accEvent (which are passed to the procedure event). The only events handled are Update, which draws a string, and MouseDown which merely beeps. Finally, the Close procedure Disposes the window. That's all it does. The next thing to notice is that there are some data types referenced that MacPascal does not recognize. Scanning through the code we encounter a DeviceControlRec, and then the ParamBlockRec. Further examination reveals the type WindowPeek which is used once in the Open procedure. We will deal with these three types in a moment. The final thing is the toolbox calls used by the DA. We will declare equivalent procedures to these and use "inline" to make the actual calls. It will be very straightforward with one minor twist.

Now let's get back to the type declarations. DeviceControlRec is not found anywhere in Inside Macintosh! As it turns out, if you read the portion of the Desk Manager on "writing your own Desk Accessories" it will mention the three driver routines used and then refer you to the Device Manager for further details. In the Device Manager chapter they mention that all driver routines recieve a pointer to the calls parameter block in A0 (there's the ParamBlockRec), and a pointer to the "Device Control Entry" in A1. On page 21, titled "A Device Control Entry" we find the description of what must be the DeviceControlRec. The description is not a Pascal type declaration but we can easily convert it into one. The only fields accessed by the simple DA are the dctlRefNum, and dctlWindow. DctlRefNum is the reference number of the driver (related to the number of the DA), and dctlWindow is a place to put a pointer to the window the DA uses. Once you become familiar with DA's the use of the other fields is easily found.

The declaration of a ParamBlockRec is found in that same chapter. If we read the DA carefully we see that csCode and csParam are the only parts referenced, so we won't type all four of the variant parts, only what is needed. CsParam is declared as array[0..0] of Byte which seems real stupid and dangerous to me so I changed it to array[0..3] of Byte. In the DA csParam is used only as a pointer to an event record. It would be convenient to change the definition of csParam to ^EventRecord, but let's stay with the standard form. IM assumes that all DA's (and all drivers) are written in assembly language. In assembly you can use csParam any way you wish. In Pascal the type checking gets in the way, so I have adopted the habit of useing BlockMove to copy things into an out of csParam.

To find the definition of WindowPeek we look, naturally, in the Window Manager chapter of IM. To use this definition we must also provide declarations for a Handle, and for a StringHandle. As I mentioned in previous articles, MacPascal allocates 2 bytes for boolean types while Lisa Pascal allocates 1 byte (1 is correct). We take this into account in the declaration.

We are now ready to do the Type declarations, so here they are:

Type Declarations for the Sample DA

 type
    Lptr = ^longint;
    ptr = ^integer;
    Handle = ^ptr;
    Byte = 0..255;
    str255P = ^str255;
    stringHandle = ^str255;

  ParamBlockRec = record
      qLink : Ptr;
      qType : integer;
      ioTrap : integer;
      ioCmdAddr : ptr;
      ioCompletion : ptr;
      ioResult : integer;
      ioNamePtr : ^str255;
      ioVrefNum : integer;
      { Usually there are three variant parts here also. }
      { DA's use only csCode and csParam. }
      csCode : integer;
      csParam : array[0..3] of Byte;
   end;

  ParamBlkPtr = ^ParamBlockRec;

  WindowPtr = GrafPtr;
  WindowPeek = ^WindowRecord;

  WindowRecord = record
       port : GrafPort;
       windowKind : Integer;
       visible : Boolean;
       {hilited : Boolean; }
       goAwayFlag : Boolean;
       {spareFlag : Boolean; }
       strucRgn : RgnHandle;
       contRgn : RgnHandle;
       updateRgn : RgnHandle;
       windowDefProc : Handle;
       dataHandle : Handle;
       titleHandle : StringHandle;
       titleWidth : Integer;
       ControlList : Handle;
       nextWindow : WindowPeek;
       windowPic : PicHandle;
       refCon : LongInt;
   end;

  DeviceControlRec = record
       dCltDriver : Handle;
       DcltFlags : integer;
       dctlQueue : integer;
       DctlQHead : Lptr;
       DctlQtail : Lptr;
       DctlPosition : longint;
       DctlStorage : Handle;
       dCtlRefNum : integer;
       dCtlCurTicks : longint;
       dCtlWindow : GrafPtr;
       dCtlDelay : integer;
       dCtlEmask : integer;
       dCtlMenu : integer;
   end;

Now let's attack the issue of the toolbox calls. We will make procedure declarations for the needed routines, and use inline in those declarations. This method is clearer than using inline directly in the code. In the main procedure we will use inline directly (for brevity). The NewWindow function is going to allocate a window record on the heap, and MacPascal reacts very poorly to this (you get an out of memory error). To alleviate this problem we pass a pointer to a window record to NewWindow. We must remember later, when we are constructing the main procedure of our program, to declare a variable named GlobalWindow as a WindowRecord. The ToolBox interface is therefore:

ToolBox Interface routines

{--- Toolbox routines used by  DA -----------------------}
{ NewWindow used by Open. }
{ Uses GlobalWindow variable for WindowRecord instead of  }
{ letting the system allocate the memory automatically. }

 function NewWindow (wStorage : ptr;
       boundsRect : Rect;
                        title : str255;
      visible : boolean;
                  procID : integer;
      behind : windowPtr;
       goAwayFlag : boolean;
                   refcon : longint) : WindowPtr;
 begin
    NewWindow := pointer(LinlineF($A913, @GlobalWindow,
                                 @boundsRect, @title, visible, procID,
   behind, goAwayFlag, refcon));
 end;
 procedure BeginUpdate (TheWindow : WindowPtr);
 begin
      inlineP($A922, TheWindow);
 end;
 procedure EndUpdate (TheWindow : WindowPtr);
 begin
      inlineP($A923, TheWindow);
 end;
 procedure DisposeWindow (TheWindow : WindowPtr);
 begin
      inlineP($A914, TheWindow);
 end;
{---------------------------------------------------------------------}

At this point all we have is enough declarations to survive a command-K check without getting a bug box. We still don't have the DA doing anything. The routines to operate the DA will all be contained in the main procedure, and all their variables will be declared as global. You will find the program at the end of this article. Now we will step-step through the system simulation that will run the sample DA.

If you follow along in the code you'll see that the first command is to remove the menu hilite created by the Go command. We then set the dctlRefNum as if the system were opening the DA and that were its driver reference number. What the DA will do is set the WindowKind field of the DA's window to this number. Actually, if the WindowKind of any window is negative the Window Manager will not treat it normally. It therefore becomes necessary to cheat a little and use a positive number for dctlRefNum. Note that the same applies to the Menu Manager. Our sample DA does not use a menu, but if it did we would have to make that menu's id number positive or it would not be treated normally (Normally for an application menu that is. In a real DA we want the system to treat the menu differently.)

We then call Open, passing along the two records. Block is still not set to any values, but Open does not look for any so it doesn't matter. Open sets dctlWindow to the WindowPtr of the newly created window. Note that Open makes the new window in the back, and that immediately after the Open call the system calls SelectWindow and then ShowWindow. I know this is right because I have traced the code of the trap _OpenDeskAcc.

Now that the DA is Open, it can respond to Ctl (control) calls. When the system actually makes these calls they are of the form err:=PBControl(@Block,false), in other words, a normal device manager driver call. In a Pascal DA there is a header that converts the register based call into a procedure call. We will simply call Ctl directly. One type of control call that all DA's should respond to is those to cut and paste. Our sample DA doesn't, but we will include this in the simulation. To do this we will need a menu, like the Edit menu in an application, to generate the cut and paste commands. This is the purpose of the NewMenu call after Open.

At this point we enter an event loop. The variable "quit" is set to false and we will loop until it is true. The first thing the larger event loop does is enter a smaller loop that waits for an event to occur. There are two types of control call that DA's can receive that are not connected with an event. These are to set the cursor and perform a periodic action. We will not concern ourselves with the timing of the periodic action, or when the DA should set the cursor. Instead we will just make Ctl calls of these two types until an event occurs. Seehow easy it is to make a Ctl call: simply set the csCode and call Ctl.

Once an event occurs it is the system's job to decide if the event should go to a DA or somewhere else. We will go ahead and set up Block for an accEvent call and change it later if needed. In general a DA receives only update events unless it is the front window, in which case it gets almost all of the events. Rather than checking that now, we'll case out the event and check each event on an indivual basis to see which window should receive it. A good example is the first case, KeyDown. If the DA is in front then we make a Ctl call (already set up as type accEvent). Otherwise we do nothing, as the dormant MacPascal windows won't receive events.

The next case is that of a MouseDown. For a mouse click we'll need another case statement to handle the various places the click could have landed. FindWindow will return a code that indicates where, and in which windoow, the click occured. No matter where the click was, if it was in a window, then that window should be in front. So, we call SelectWindow. The variable "fnd'' is an integer that holds the code returned by FindWindow. We will handle the possibilities one at a time, and in numerical order. To understand the action of FindWindow better, consult the Window Manager chapter of Inside Mac.

If the MouseDown was in the menu bar then we should call the Menu Manager function MenuSelect to find which menu item the user wants to choose. MenuSelect returns a Longint with different information in the upper and lower words. If the HiWord is equal to dctlMenu then the user has chosen the DA's menu; csCode is set to accMenu, and csParam is set to the MenuSelect result. Note that the application handles the menu events, not the DA. By the time the DA finds out about it the menu has already been clicked, dragged, and released (MenuSelect does this). The DA uses the Longint MenuSelect result to determine what happened. If the HiWord from MenuSelect is not dctlMenu then it could be the Edit menu (a DA is not concerned with the others). I have arranged the menu put up earlier so that if we add 67 to the number of the menu item chosen it conveniently becomes the correct csCode for editing. We make a Ctl call accordingly.

If the MouseDown was not in the menu bar, but was in a window, then several possibilities remain. If the click was in the content portion of the window then it is that window's responsibility to handle it. Normally these clicks are returned to the application. But, if the WindowKind is negative, then the Window Manager will assume that that window belongs to a DA and make a control call. We do similarly. I found out about this the hard way. If the DA forgets to set WindowKind in Open then the window shows up but is strangely dead - this is most perplexing until you figure it out.

If the click is in the drag bar of a DA window the system will drag the window. The DA never even knows what has happened. Also, if the click is in the close box then the system calls TrackGoAway and then Close. The DA finds out this has happened whne it gets a Close call, it must then close itself. In the simulation we set "quit" and then call Close after exiting the main event loop.

We are done covering the MouseDown possibilities. All that remains are the rest of the event cases. For Update and Activate events a pointer to the window involved is in the message field of the event record. We check it, and make a Ctl call, if necessary. I am not sure how the system handles all the other event possibilities, so I pass them to the DA just in case.

This covers all the functions of the DA Prototyping Program. I have used this program, or one of its cousins, to develop several different DA's, including the one presented in this column in November '85. I think that it is a very useful tool, and I hope you find it useful, too.

DA Prototyping Program
program Run_A_DA;
    uses
      quickdraw2;

{ Put type declarations here }

 var { Variables for main simulation of system. }
     {  NOT for use by the DA }
     device : DeviceControlRec;{ passed to DA }
     block : ParamBlockRec;{ passed to DA }
     sysEv : eventRecord;
     sysMenu : MenuHandle;
     poi : point;
     wPeek : WindowPeek;
     r : rect;
     fnd : integer;
     quit : boolean;
     lll : longint;
     GlobalWindow : WindowRecord;
   
{ Put ToolBox interface routines here }

{ Put sample DA code here }

{*******************************************************}
{** Everything below this line is the simulation of the ****}
{** system running the DA and should not be changed **}
{*******************************************************}
begin { of main simulation of system handling desk acc. }
  { Desk Accessory simulation by Alan Wootton 11/11/85 }
  
   inlineP($A938, 0);{ HiliteMenu(0); remove Run hilite }
  
   device.dctlRefNum := -1 * (16 + 1);{ make this DA #16  }
  { Actually there is a problem with using negative numbers }
  { like a real DA would, so we change it to a positive number. }
   device.dctlRefNum := -device.dctlRefNum;
  { If the DA has owned Resources it may have trouble finding
     them. }
   Open(device, block);{ Open the DA }
  
   inlineP($A91F, device.dctlWindow);{ SelectWindow }
   inlineP($A915, device.dctlWindow);{ ShowWindow }
  
  { Make a menu to simulate the applications Edit menu. }
   sysMenu := Pointer(LinlineF($A931, 13, 'sysEDIT'));
          {NewMenu(13,'sysEdit'}
   inlineP($A933, sysMenu, 'undo');{AppendMenu}
   inlineP($A933, sysMenu, '??');{AppendMenu}
   inlineP($A933, sysMenu, 'cut');{AppendMenu}
   inlineP($A933, sysMenu, 'copy');{AppendMenu}
   inlineP($A933, sysMenu, 'paste');{AppendMenu}
   inlineP($A933, sysMenu, 'clear');{AppendMenu}
   inlineP($A935, sysMenu, 0);{ InsertMenu }
   inlineP($A937);{DrawMenuBar}
  
   quit := false;

   repeat { until quit }
       begin
     
 repeat { accRun and accCursor until an event occurs  }
     begin
            { actually these shouldn't happen all the time like 
                         they do here }
 block.cscode := 65; { accRun }
 Ctl(device, block);{ Device Manager Control call }
 block.cscode := 66; { accCursor }
 Ctl(device, block);{ Device Manager Control call }
     end
 until getnextevent(-1, SysEv);
     
     { set up block to make a control call of type accEvent }
 block.cscode := 64;
 lll := ord(@SysEv);
 BlockMove(@lll, @Block.csParam[0], 4);
     
 case SysEv.what of
     3, 5 :       {  key, or key repeat event  }
           if (LinlineF($A924)=ord(device.dctlWindow)) then
         {   if  FrontWindow = device.dctlWindow then }
      Ctl(device, block);
     1 :      { if mousedown event }
      begin
  poi := SysEv.where;
  fnd := winlineF($A92C, poi, @wPeek);
  { Findwindow( poi, wPeek) }
  if fnd > 0 then { if not on desktop }
      begin
 if fnd > 1 then
      inlineP($A91F, wPeek);{ SelectWindow }
 case fnd of
     1 :      {  mouse down is in MenuBar }
      begin
  lll := LinlineF($A93D, poi);
 {  lll:=MenuSelect(poi) }
  if hiword(lll) = device.dctlMenu then
      begin 
 { if dctlMenu selected then make accMenu call }
  block.csCode := 67;
                { 67 is accMenu }
  BlockMove(@lll, 
                  @Block.csParam[0], 4);
  Ctl(device, block);
      end
  else
      begin
  if Hiword(lll) = 13 then
 { Applications Edit menu? }
      begin
          {  if mouse down in app.'s Edit}
          { then make accUndo..accClear} 
          { call }
              Block.csCode := 
 loword(lll) + 67;
  Ctl(device, block);
      end;
        inlineP($A938, 0);{ HiliteMenu(0 }
   end;
              end;
     3, 5 : { if in content or grow part of window}
 if (wPeek^.windowKind = 
 device.dctlRefNum) then
       Ctl(device, block);
     4 :{ if in drag bar then drag window, }
          { no control call }

      begin
   setrect(r, -999, -999, 999, 999);
   inlineP($A925, wPeek, poi, r);
 { DragWindow }
      end;
     6 :  
 { if in GoAway box of DA window then make close call }

        if winlineF($A91E, wPeek, poi) > 0 then 
 { if TrackGoAway  then }
    if (wPeek^.windowKind = 
           device.dctlRefNum) then
        quit := true;
    { make close call later and end simulation }
     otherwise
        ;
 end{ case of  fnd }
     end;{ of if fnd>0 }
      end;{ case  mousedown }
     6, 8 :    {  if  update, or activate event then make      accEvent 
control call  }
  if sysev.message = 
                         ord(device.dctlWindow) then
       Ctl(device, block);
     otherwise
           Ctl(device, block);{ send other events to acc ??? }
    end;{ of case of event.what }
       end{ of repeat }
   until quit;
  
   Close(device, block);
    { Application ( or system ) calls CloseDeskAcc }
  
end.{  of program, and of article, see 'ya next month}

Only MacTutor brings you quality programming information month after month. Subscribe now!

 

Community Search:
MacTech Search:

Software Updates via MacUpdate

GraphicConverter 10.5.4 - $39.95
GraphicConverter is an all-purpose image-editing program that can import 200 different graphic-based formats, edit the image, and export it to any of 80 available file formats. The high-end editing... Read more
Dash 4.1.3 - Instant search and offline...
Dash is an API documentation browser and code snippet manager. Dash helps you store snippets of code, as well as instantly search and browse documentation for almost any API you might use (for a full... Read more
Microsoft OneNote 16.9 - Free digital no...
OneNote is your very own digital notebook. With OneNote, you can capture that flash of genius, that moment of inspiration, or that list of errands that's too important to forget. Whether you're at... Read more
DEVONthink Pro 2.9.17 - Knowledge base,...
Save 10% with our exclusive coupon code: MACUPDATE10 DEVONthink Pro is your essential assistant for today's world, where almost everything is digital. From shopping receipts to important research... Read more
OmniGraffle 7.6 - Create diagrams, flow...
OmniGraffle helps you draw beautiful diagrams, family trees, flow charts, org charts, layouts, and (mathematically speaking) any other directed or non-directed graphs. We've had people use Graffle to... Read more
iFinance 4.3.7 - Comprehensively manage...
iFinance allows you to keep track of your income and spending -- from your lunchbreak coffee to your new car -- in the most convenient and fastest way. Clearly arranged transaction lists of all your... Read more
Opera 50.0.2762.58 - High-performance We...
Opera is a fast and secure browser trusted by millions of users. With the intuitive interface, Speed Dial and visual bookmarks for organizing favorite sites, news feature with fresh, relevant content... Read more
Microsoft Office 2016 16.9 - Popular pro...
Microsoft Office 2016 - Unmistakably Office, designed for Mac. The new versions of Word, Excel, PowerPoint, Outlook and OneNote provide the best of both worlds for Mac users - the familiar Office... Read more
SoftRAID 5.6.4 - High-quality RAID manag...
SoftRAID allows you to create and manage disk arrays to increase performance and reliability. SoftRAID allows the user to create and manage RAID 4 and 5 volumes, RAID 1+0, and RAID 1 (Mirror) and... Read more
OmniGraffle Pro 7.6 - Create diagrams, f...
OmniGraffle Pro helps you draw beautiful diagrams, family trees, flow charts, org charts, layouts, and (mathematically speaking) any other directed or non-directed graphs. We've had people use... Read more

Latest Forum Discussions

See All

Around the Empire: What have you missed...
Around this time every week we're going to have a look at the comings and goings on the other sites in Steel Media's pocket-gaming empire. We'll round up the very best content you might have missed, so you're always going to be up to date with the... | Read more »
The 7 best games that came out for iPhon...
Well, it's that time of the week. You know what I mean. You know exactly what I mean. It's the time of the week when we take a look at the best games that have landed on the App Store over the past seven days. And there are some real doozies here... | Read more »
Popular MMO Strategy game Lords Mobile i...
Delve into the crowded halls of the Play Store and you’ll find mobile fantasy strategy MMOs-a-plenty. One that’s kicking off the new year in style however is IGG’s Lords Mobile, which has beaten out the fierce competition to receive Google Play’s... | Read more »
Blocky Racing is a funky and fresh new k...
Blocky Racing has zoomed onto the App Store and Google Play this week, bringing with it plenty of classic kart racing shenanigans that will take you straight back to your childhood. If you’ve found yourself hooked on games like Mario Kart or Crash... | Read more »
Cytus II (Games)
Cytus II 1.0.1 Device: iOS Universal Category: Games Price: $1.99, Version: 1.0.1 (iTunes) Description: "Cytus II" is a music rhythm game created by Rayark Games. It's our fourth rhythm game title, following the footsteps of three... | Read more »
JYDGE (Games)
JYDGE 1.0.0 Device: iOS Universal Category: Games Price: $4.99, Version: 1.0.0 (iTunes) Description: Build your JYDGE. Enter Edenbyrg. Get out alive. JYDGE is a lawful but awful roguehate top-down shooter where you get to build your... | Read more »
Tako Bubble guide - Tips and Tricks to S...
Tako Bubble is a pretty simple and fun puzzler, but the game can get downright devious with its puzzle design. If you insist on not paying for the game and want to manage your lives appropriately, check out these tips so you can avoid getting... | Read more »
Everything about Hero Academy 2 - The co...
It's fair to say we've spent a good deal of time on Hero Academy 2. So much so, that we think we're probably in a really good place to give you some advice about how to get the most out of the game. And in this guide, that's exactly what you're... | Read more »
Everything about Hero Academy 2: Part 3...
In the third part of our Hero Academy 2 guide we're going to take a look at the different modes you can play in the game. We'll explain what you need to do in each of them, and tell you why it's important that you do. [Read more] | Read more »
Everything about Hero Academy 2: Part 2...
In this second part of our guide to Hero Academy 2, we're going to have a look at the different card types that you're going to be using in the game. We'll split them up into different sections too, to make sure you're getting the most information... | Read more »

Price Scanner via MacPrices.net

Apple restocked Certified Refurbished 13″ Mac...
Apple has restocked a full line of Certified Refurbished 2017 13″ MacBook Airs starting at $849. An Apple one-year warranty is included with each MacBook, and shipping is free: – 13″ 1.8GHz/8GB/128GB... Read more
How to find the lowest prices on 2017 Apple M...
Apple has Certified Refurbished 13″ and 15″ 2017 MacBook Pros available for $200 to $420 off the cost of new models. Apple’s refurbished prices are the lowest available for each model from any... Read more
The lowest prices anywhere on Apple 12″ MacBo...
Apple has Certified Refurbished 2017 12″ Retina MacBooks available for $200-$240 off the cost of new models. Apple will include a standard one-year warranty with each MacBook, and shipping is free.... Read more
Apple now offering a full line of Certified R...
Apple is now offering Certified Refurbished 2017 10″ and 12″ iPad Pros for $100-$190 off MSRP, depending on the model. An Apple one-year warranty is included with each model, and shipping is free: –... Read more
27″ iMacs on sale for $100-$130 off MSRP, pay...
B&H Photo has 27″ iMacs on sale for $100-$130 off MSRP. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 27″ 3.8GHz iMac (MNED2LL/A): $2199 $100 off MSRP – 27″ 3.... Read more
2.8GHz Mac mini on sale for $899, $100 off MS...
B&H Photo has the 2.8GHz Mac mini (model number MGEQ2LL/A) on sale for $899 including free shipping plus NY & NJ sales tax only. Their price is $100 off MSRP. Read more
Apple offers Certified Refurbished iPad minis...
Apple has Certified Refurbished 128GB iPad minis available today for $339 including free shipping. Apple’s standard one-year warranty is included. Their price is $60 off MSRP. Read more
Amazon offers 13″ 256GB MacBook Air for $1049...
Amazon has the 13″ 1.8GHz/256B #Apple #MacBook Air on sale today for $150 off MSRP including free shipping: – 13″ 1.8GHz/256GB MacBook Air (MQD42LL/A): $1049.99, $150 off MSRP Read more
9.7-inch 2017 WiFi iPads on sale starting at...
B&H Photo has 9.7″ 2017 WiFi #Apple #iPads on sale for $30 off MSRP for a limited time. Shipping is free, and pay sales tax in NY & NJ only: – 32GB iPad WiFi: $299, $30 off – 128GB iPad WiFi... Read more
Wednesday deal: 13″ MacBook Pros for $100-$15...
B&H Photo has 13″ #Apple #MacBook Pros on sale for up to $100-$150 off MSRP. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 13-inch 2.3GHz/128GB Space Gray... Read more

Jobs Board

*Apple* Store Leader - Retail District Manag...
Job Description: Job Summary As more and more people discover Apple , they visit our retail stores seeking ways to incorporate our products into their lives. It's Read more
Sr. Experience Designer, Today at *Apple* -...
# Sr. Experience Designer, Today at Apple Job Number: 56495251 Santa Clara Valley, California, United States Posted: 18-Jan-2018 Weekly Hours: 40.00 **Job Summary** Read more
Security Applications Engineer, *Apple* Ret...
# Security Applications Engineer, Apple Retail Job Number: 113237456 Santa Clara Valley, California, United States Posted: 17-Jan-2018 Weekly Hours: 40.00 **Job Read more
*Apple* Solutions Consultant - Apple (United...
# Apple Solutions Consultant Job Number: 113384559 Brandon, Florida, United States Posted: 10-Jan-2018 Weekly Hours: 40.00 **Job Summary** Are you passionate about Read more
Art Director, *Apple* Music + Beats1 Market...
# Art Director, Apple Music + Beats1 Marketing Design Job Number: 113258081 Santa Clara Valley, California, United States Posted: 05-Jan-2018 Weekly Hours: 40.00 Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.