TweetFollow Us on Twitter

Screen Buffer
Volume Number:1
Issue Number:9
Column Tag:Modula 2 Mods

"Using the Alternate Screen Buffer"

By Tom Taylor, Software Engineer, Modula-2 Corp., Provo, Ut., MacTutor Contributing Editor

This article discusses the "alternate screen" capabilities of the Macintosh and presents a module that allows easy access to this facility from MacModula-2.

The Alternate Screen

As far as I know, Inside Macintosh only mentions the alternate screen buffer in two places: in the Memory Manager Programmer's Guide and in the Segment Loader Programmer's Guide. The Memory Manager section simply says, "There are alternate screen and sound buffers for special applications. If you use either or both of these, the space available for use by your application is reduced accordingly..." The alternate screen buffer can be used for high-speed flicker free graphics or a slide show program. For example, an application can be drawing in one screen while displaying a different screen. The popular "Tumbling Mac" demo by Mainstay uses the alternate screen buffer to create a high-speed flicker-free animation application. According to figure 1, the alternate screen buffer is allocated 32768 bytes below the main screen buffer.

Figure 1. Partial memory map showing sizes of various buffers.

The Segment Loader section mentions that the Chain and Launch traps configure memory for the sound and screen buffers. Whenever one of these traps is called, a parameter is passed that determines how these buffers are set up. The word (16-bit) parameter has three possible values:

Zero - Only the main sound and screen buffers are allocated. This is the normal situation and gives an application the most possible memory.

Negative - The alternate sound buffer and main screen buffer is allocated.

Positive - Both the alternate sound and screen buffers are allocated.

A Screen Switcher Module

Instead of building a specific program to demonstrate the alternate screen in Modula-2, this article presents a library module that can be used in many different programs in many different types of applications. This article will also present a small program that uses the developed screen switcher module.

A screen switcher module should support at least four functions:

• launch a program with the alternate screen,

• copy the main screen into the alternate screen,

• change the screen back and forth between the main and alternate screens, and

• set the screen buffer to the main screen before a program exits.

Apparently, the Finder always launches a program with the main sound and screen buffers (parameter set to 0). In order for a program to use the alternate screen, the program must be re-launched with the appropriate parameter (-1). The procedure LaunchWithAltScreen re-launches the program with the alternate screen if the alternate screen is not already allocated.

Here are the Definition and Implementation modules for handling the alternate screen:

DEFINITION MODULE ScreenSwitcher;

  EXPORT QUALIFIED
    LaunchWithTwoScreens,
    CopyScreens,
    SwitchScreens,
    SetMainScreen;
  
  PROCEDURE LaunchWithTwoScreens;
    (* This procedure re-launches the
       current program with the alternate
       screen.  If the alternate screen is
       already installed, this procedure 
       does nothing. *)

  PROCEDURE CopyScreens;
    (* CopyScreens copies the main screen
       into the alternate screen. *)
  
  PROCEDURE SwitchScreens;
    (* SwitchScreens alternately switches
       what is being displayed from the
       one screen to the other. *)
  
  PROCEDURE SetMainScreen;
    (* Sets the current screen buffer to
       the main screen so that when the
       program exits to the Finder
       the screen will be the right one. *)
  
END ScreenSwitcher.

IMPLEMENTATION MODULE ScreenSwitcher;

  FROM Launcher IMPORT
          CountAppFiles,
   LaunchRec,
   Launch;

  FROM Terminal IMPORT
          WriteString;

  FROM MacSystemTypes IMPORT
          Str255, LongCard;

  FROM Strings IMPORT
          StrModToMac;

  FROM SYSTEM IMPORT
          ADR, WORD, ADDRESS;

  FROM MacInterface IMPORT
          thePort;

  FROM QuickDraw1 IMPORT
          GrafPtr;

  CONST
    vBufA = 1e00h; (* Buffer A offset from
                                VIA interface chip *)
    vPage2 = 1;    (* This is a bit into
                              vBufA, if 0, select
                              alternate screen *)

  TYPE
    ScreenPtr
        = POINTER TO ARRAY [1..10944] OF
                 WORD;
      (* The Mac screen buffer is 10944
           16-bit words long *)

    FlagsPtr
        = POINTER TO BITSET;

  VAR
    CurPageOption [936h] : INTEGER;
       (* Mac global variable containing
           value of parameter at launch time
           that determines sound and screen
           buffers. *)
    ScrnBase [824h] : ScreenPtr;
       (* Mac global containing address of
           main screen. *)
    AltBase : ScreenPtr;
       (* Our homebrew alternate screen
            pointer. *)
    VIA6522Chip [1d4h] : FlagsPtr;
       (* VIA base address - from MDS's
           SysEqu.txt *)
    BufferA : FlagsPtr;
       (* Our pointer to vBuffer A *)
    originalPort  : GrafPtr;
       (* Save GrafPtr to whole screen *)

  PROCEDURE LaunchWithTwoScreens;
    VAR
      PrintOrWhat, count : INTEGER;
      launchRec : LaunchRec;
      prog : Str255;
  BEGIN
    IF CurPageOption >= 0 THEN
      CountAppFiles(PrintOrWhat,count);
        (* Get the number of Modula-2
            programs launched.  It better
            be one... this one! *)
      IF count # 1 THEN
        WriteString('Double-click the ');
        WriteString('program icon to start');
        WriteString(' the program');
        HALT;
      END;
      StrModToMac(prog,'Modula-2');
      launchRec.Name := ADR(prog);
      launchRec.SoundScreenBuffer := -1;
      Launch(launchRec);
    END;
  END LaunchWithTwoScreens;
  
  PROCEDURE CopyScreens;
  BEGIN
    AltBase^ := ScrnBase^;
  END CopyScreens;
  
  PROCEDURE SwitchScreens;
  BEGIN
    (* According to the MDS SysEqu.Txt
        file, the vPage2 bit in the BufferA
        flags is zero for the alternate
        screen and one for the main screen.
     *)
    WITH originalPort^.portBits DO
      IF baseAddr = ADDRESS(ScrnBase)
      THEN
          (* Graphical operations apply
              to alternate screen while
              displaying main screen. *)
 baseAddr := ADDRESS(AltBase);
 INCL(BufferA^,vPage2);
          (* Turn on bit *)
      ELSE
          (* Graphical operations apply
              to main screen while displaying
              alternate screen. *)
 baseAddr := ADDRESS(ScrnBase);
 EXCL(BufferA^,vPage2);
          (* Turn off  bit *)
      END;
    END;
  END SwitchScreens;
  
  PROCEDURE SetMainScreen;
  BEGIN
    IF NOT(vPage2 IN BufferA^) THEN
      SwitchScreens;
    END;
  END SetMainScreen;

BEGIN
  AltBase := ScrnBase;
   (* Set up pointer to alt screen *)
  DEC(AltBase,32768);
  
  BufferA := VIA6522Chip;
   (* Set up pointer to Buffer A flags *)
  INC(BufferA,vBufA);
  
   (* Save screen GrafPort *)
  originalPort := thePort;
END ScreenSwitcher.

            Here is a program module that actually uses the ScreenSwitcher module.  The 
program simply bounces a picture of a Lisa computer around the screen.  The program draws 
the picture in one screen, switches screens, erases the old picture, moves to a new position, 
draws the picture, and switches to the other screen and applies the same sequence of operations. 
 In order for this program to run properly, it is important to have this program and the 
Modula-2 program on the system disk.  Click the mouse to exit the program.

MODULE Animate;

  FROM QuickDraw1 IMPORT
          QDPtr, StuffHex, HideCursor,
          BitMap, Rect, SetRect,
          srcOr, srcBic, OffsetRect,
          Random;

  FROM QuickDraw2 IMPORT
          CopyBits;
   
  FROM MacSystemTypes IMPORT
          Str255;
   
  FROM Strings IMPORT
          StrModToMac;

  FROM SYSTEM IMPORT
          ADR, WORD;

  FROM MacInterface IMPORT
          thePort, Write;

  FROM EventManager IMPORT
          Button;

  FROM ScreenSwitcher IMPORT
          LaunchWithTwoScreens,
          CopyScreens, SwitchScreens;

  VAR
    icon : ARRAY [0..95] OF WORD;
       (* Storage to hold icon data *)
    x, y : ARRAY [0..1] OF INTEGER;
       (* coordinates of icon for each
           screen *)
    screen : [0..1];
       (* current screen reminder *)
    xDir, yDir : INTEGER;
       (* offset for each icon move *)
 
  PROCEDURE InitIcon;

    PROCEDURE MyStuffHex(ptr: QDPtr;
                         s : ARRAY OF CHAR);
    (* This procedure isolates the body of
       InitIcon from having to convert
       the Modula-style hex strings to
       Pascal format *)
      VAR
 macStr : Str255;
    BEGIN
      StrModToMac(macStr,s);
      StuffHex(ptr,macStr);
    END MyStuffHex;

  BEGIN
    (* Picture of a Lisa hoisted from
        Apple's QDSample program *)
    MyStuffHex(ADR(icon[ 0]),
'000000000000000000000000000000000000001FFFFFFFFC');
    MyStuffHex(ADR(icon[12]),
'00600000000601800000000B0600000000130FFFFFFFFFA3');
  MyStuffHex(ADR(icon[24]),
'18000000004311FFFFF00023120000080F231200000BF923');
    MyStuffHex(ADR(icon[36]),
'120000080F23120000080023120000080023120000080F23');
    MyStuffHex(ADR(icon[48]),
'1200000BF923120000080F2312000008002311FFFFF00023');
    MyStuffHex(ADR(icon[60]),
'08000000004307FFFFFFFFA30100000000260FFFFFFFFE2C');
    MyStuffHex(ADR(icon[72]),
'18000000013832AAAAA8A9F0655555515380C2AAAA82A580');
    MyStuffHex(ADR(icon[84]),
'800000000980FFFFFFFFF300800000001600FFFFFFFFFC00');
  END InitIcon;

  PROCEDURE DrawIcon(h,v: INTEGER;  mode : INTEGER);
    VAR
      srcBits : BitMap;
      srcRect, dstRect : Rect;
  BEGIN
    srcBits.baseAddr := ADR(icon);
    srcBits.rowBytes := 6;
    SetRect(srcBits.bounds,0,0,48,32);
    srcRect := srcBits.bounds;
    dstRect := srcRect;
    OffsetRect(dstRect,h,v);
    CopyBits(srcBits,thePort^.portBits,
                  srcRect,dstRect,mode,NIL);
  END DrawIcon;

  PROCEDURE MoveIcon;
  BEGIN
    (* Erase the old icon *)
    DrawIcon (x[screen],y[screen], srcBic);
    (* Calculate new position *)
    x[screen] := x[1-screen] + xDir;
    (* Don't let icon go off screen *)
    IF (x[screen] < 0) OR (x[screen] > 460) 
    THEN
      xDir := -xDir;
    END;
    y[screen] := y[1-screen] + yDir;
    IF (y[screen] < 0) OR (y[screen] > 310) 
    THEN
      yDir := -yDir;
    END;
    (* Draw the icon *)
    DrawIcon(x[screen],y[screen],srcOr);
    (* Swap our screen reminder *)
    screen := 1 - screen;
  END MoveIcon;
  
BEGIN
  HideCursor;
  (* Re-launch ourself with alt. screen *)
  LaunchWithTwoScreens;
  InitIcon;
  Write(14c); (* Clear Screen *)
  CopyScreens;
  screen := 0;
  x[0] := 100;
  y[0] := 100;
  x[1] := 100;
  y[1] := 100;
  xDir := 1;
  yDir := 1;
  WHILE NOT Button() DO
    MoveIcon;
    SwitchScreens;
  END;
END Animate.
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Civilization VI 1.0.6 - Next iteration o...
Sid Meier’s Civilization VI is the next entry in the popular Civilization franchise. Originally created by legendary game designer Sid Meier, Civilization is a strategy game in which you attempt to... Read more
djay Pro 2.0.1 - Transform your Mac into...
djay Pro provides a complete toolkit for performing DJs. Its unique modern interface is built around a sophisticated integration with iTunes and Spotify, giving you instant access to millions of... Read more
Microsoft OneNote 15.41 - Free digital n...
OneNote is your very own digital notebook. With OneNote, you can capture that flash of genius, that moment of inspiration, or that list of errands that's too important to forget. Whether you're at... Read more
TechTool Pro 9.6 - Hard drive and system...
TechTool Pro has long been one of the foremost utilities for keeping your Mac running smoothly and efficiently. With the release of version 9, it has become more proficient than ever. TechTool... Read more
Apple iOS 11.2.1 - The latest version of...
iOS 11 sets a new standard for what is already the world’s most advanced mobile operating system. It makes iPhone better than before. It makes iPad more capable than ever. And now it opens up both to... Read more
Things 3.3 - Elegant personal task manag...
Things is a task management solution that helps to organize your tasks in an elegant and intuitive way. Things combines powerful features with simplicity through the use of tags and its intelligent... Read more
RapidWeaver 7.5.5 - Create template-base...
RapidWeaver is a next-generation Web design application to help you easily create professional-looking Web sites in minutes. No knowledge of complex code is required, RapidWeaver will take care of... Read more
Adobe Animate CC 2018 18.0.1.115 - Anima...
Animate CC 2018 is available as part of Adobe Creative Cloud for as little as $19.99/month (or $9.99/month if you're a previous Flash Professional customer). Animate CC 2018 (was Flash CC) lets you... Read more
Postbox 5.0.22 - Powerful and flexible e...
Postbox is a new email application that helps you organize your work life and get stuff done. It has all the elegance and simplicity of Apple Mail, but with more power and flexibility to manage even... Read more
Tunnelblick 3.7.4b - GUI for OpenVPN.
Tunnelblick is a free, open source graphic user interface for OpenVPN on OS X. It provides easy control of OpenVPN client and/or server connections. It comes as a ready-to-use application with all... Read more

Latest Forum Discussions

See All

Rules of Survival guide - how to boost y...
It's not easy surviving in the "every-man-for-himself" world of Rules of Survival. You'll be facing off against many other players who might be more skilled than you, or are luckier than you. There are a lot of factors weighing against you. With... | Read more »
FEZ Pocket Edition (Games)
FEZ Pocket Edition 1.0 Device: iOS Universal Category: Games Price: $4.99, Version: 1.0 (iTunes) Description: | Read more »
Amazing Katamari Damacy guide - beginner...
Amazing Katamari Damacy brings the bizarro world of the original games to mobile and shifts them into an endless format that's just as addictive as the PlayStation entries. Your goal is still to roll as much random stuff as you possibly can, though... | Read more »
Portal Knights guide - crafting tips and...
In Portal Knights, you're only as strong as the items you have at your disposal. This sandbox adventure is all about crafting and building up the next big thing. Whether you're an avid explorer or collector, crafting will likely play a large part... | Read more »
The best deals on the App Store this wee...
A new week means new discounts on the App Store. This week's deals run the gamut of action-adventure titles, puzzle games, and one of the best narrative adventure series out there. If you're looking to fill out your mobile gaming library on a... | Read more »
What you need to know about Animal Cross...
We hope you've been hard at work on collecting all of those holiday items in Animal Crossing: Pocket Camp, because you're about to get a whole new list of fun things to do as the game receives its first big update sometime soon. There are a lot of... | Read more »
Reigns: Her Majesty guide - how to use e...
Ruling a kingdom isn't easy--doubly so for a queen whose every decision is questioned by the other factions seeking a slice of power. Reigns: Her Majesty builds on the original game's swipey tactics, adding items that you can use to move the story... | Read more »
The best new games we played this week -...
Friday has crept up on us once again, so it's time to honor the best new games we've played over the past few days. This past week was a pretty exciting one, with the debut of lots of beautiful new indies and some familiar faces returning to the... | Read more »
Portal Knights guide- beginner tips and...
Portal Knights is finally making the jump to iOS and Android, and it's already climbing the ranks to become the next big MMO experience on mobile. This sprawling sandbox game will let you pursue any adventure you wish, whether you want to sling... | Read more »
Reigns: Her Majesty guide - how to swipe...
Reigns: Her Majesty is storming the App Store this week, bringing more tinder-esque kingdom building to eager players everywhere. If you've played the original Reigns, you'll know that leading a kingdom is never easy. It's a careful balancing act... | Read more »

Price Scanner via MacPrices.net

Beats Holiday sale at B&H, headphones and...
B&H Photo has Beats by Dr. Dre headphones, earphones, and speakers on sale for up to $80 off MSRP as part of their Holiday sale. Expedited shipping is free, and B&H charges sales tax to NY... Read more
Holiday sale: Apple resellers offer 2017 15″...
MacMall has 15″ MacBook Pros on sale for $220-$300 off MSRP, each including free shipping: – 15″ 2.8GHz MacBook Pro Space Gray (MPTR2LL/A): $2179, $220 off MSRP – 15″ 2.8GHz MacBook Pro Silver (... Read more
Holiday sale: Apple resellers offer 13″ MacBo...
B&H Photo has 13″ MacBook Pros on sale for up to $150 off MSRP. Shipping is free, and B&H charges sales tax for NY & NJ residents only: – 13-inch 2.3GHz/128GB Space Gray MacBook Pro (... Read more
Apple Watch Series 2, Certified Refurbished,...
Apple has Certified Refurbished Apple Watch Nike+ Series 2s, 42mm Space Gray Aluminum Case with Anthracite/Black Nike Sport Bands, available for $249 (38mm) or $279 (42mm). The 38mm model was out of... Read more
Apple offers Certified Refurbished 2016 12″ R...
Apple has Certified Refurbished 2016 12″ Retina MacBooks available starting at $949. Apple will include a standard one-year warranty with each MacBook, and shipping is free. The following... Read more
B&H drops price on 13″ 256GB MacBook Air...
B&H has the 13″ 1.8GHz/256GB Apple MacBook Air (MQD42LL/A) now on sale for $1079 including free shipping plus NY & NJ sales tax only. Their price is $120 off MSRP, and it’s the lowest price... Read more
Holiday sale: 9″ iPads starting at $299, take...
MacMall has 9″ WiFi iPads on sale for $30 off including free shipping: – 9″ 32GB WiFi iPad: $299 – 9″ 128GB WiFi iPad: $399 Read more
Green Monday deal: 15″ 2.8GHz MacBook Pro on...
B&H Photo has the 15″ 2.8GHz Space Gray MacBook Pro on sale for $250 off MSRP for today only as part of their Green Monday/Holiday sale. Shipping is free, and B&H charges sales tax for NY... Read more
Green Monday sale: B&H offers 12″ Apple i...
B&H Photo has 12″ iPad Pros on sale for up to $150 off MSRP as part of their Green Monday/Holiday sale. Shipping is free, and B&H charges sales tax in NY & NJ only: – 12″ 64GB WiFi iPad... Read more
Holiday deal: 21″ and 27″ Apple iMacs on sale...
MacMall has 2017 21″ and 27″ Apple iMacs on sale for up to $200 off MSRP. Shipping is free: – 21″ 2.3GHz iMac: $999 $100 off MSRP – 21″ 3.0GHz iMac: $1199 $100 off MSRP – 21″ 3.4GHz iMac: $1379 $120... Read more

Jobs Board

QA Automation Engineer, *Apple* Pay - Apple...
# QA Automation Engineer, Apple Pay Job Number: 113202642 Santa Clara Valley, California, United States Posted: 11-Dec-2017 Weekly Hours: 40.00 **Job Summary** At Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description:SalesSpecialist - Retail Customer Service and SalesTransform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description:SalesSpecialist - Retail Customer Service and SalesTransform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Information Security - Security Data...
# Apple Information Security - Security Data Analyst Job Number: 113119545 Austin, Texas, United States Posted: 10-Nov-2017 Weekly Hours: 40.00 **Job Summary** This Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.