TweetFollow Us on Twitter

All About Printing
Volume Number:1
Issue Number:9
Column Tag:Pascal Procedures

“All About Printing”

By Alan Wootton, President, Top-Notch Productions, MacTutor Contributing Editor

This month's topic is printing. As an example I present a program that will print a message in large, 'banner' format. Perfect for parties!

To those of us who are familiar with the older generation of computers, printing is a matter of sending data through ports and using printer control codes. For the Mac we take these details for granted and will concentrate on using pre-packaged drivers and on the details of GrafPorts.

Background

Printing on the Mac is done through the Printing Manager, RAM software that is considered part of the low-level operating system software. This code is stored in the system file and loaded into RAM. The Printing Manager interfaces between your program and the actual printer driver that controls the printer. The Imagewriter and LaserPrinter files are printer drivers called by the Printing Manager. The "Choose Printer" desk accessory switches between the two drivers so the Printing Manager has the correct driver installed and ready to go. To be more specific, the Imagewriter and LaserPrinter files are printer resource files, which contain device driver code within them to drive the respective printer. The "Choose Printer" DA copies the selected printer driver and it's data structures from the printer resource file into the system file, and that's the driver that the Print Manger then uses. The idea is that a Mac application can be written using printing manager calls and be printer independent, since the printing manager would then interface to the appropriate device driver, eliminating the need to re-code an application for a different printer. This ideal comes close to being achieved on the Mac, probably more than any other computer system, but is still far from perfect.

The intent of the Mac designers was that printing would be transparent to quickdraw graphics "printed" on the screen. This was accomplished by using a special quickdraw grafport for printing. Normal quickdraw routines are used to draw into this port. The Printing Manager converts these quickdraw calls in your grafport to printer calls to drive the printer instead of the screen. In this way, printing is supposed to be transparent to a normal screen drawing operation. It also explains the complexity of printing, since it involves all the quickdraw screen graphics technology.

Draft versus Standard Quality

The Printing Manager is responsible for the dialog boxes that appear prior to printing and for allowing draft or standard quality printing. These two modes are fundamentally different. In draft mode, the ascii representation of the quickdraw calls are sent to the printer, which prints the text of the document using the character generator within the printer. Hence no graphics are supported except character graphics or modes directly supported by the printer and driven by the user's program. The printer responds to it's own command codes rather than any of the "Mac" like graphics.

Spool File versus Printing the Spool File

Standard and high quality modes are completely different. In these modes, the printer is controlled bit by bit and the entire document is converted into a giant bit mapped graphics dump. A temporary quickdraw picture is first composed on disk called the spool file. This spool file is then read into memory, converted into an array of dots by bands, and sent to the printer. The bands are necessary because of the huge amount of memory required by bit-mapping an 81/2 by 11 inch page. For the imagewriter, this amounts to 256K of memory. For the LaserWriter, over a megabyte! The task of first creating a quickdraw picture for the spool file, and then imaging (converting to a bit-map) and printing the spool file band by band, are handled seperately by the printing manager. In fact, it is supposed to be possible to create several spool files for printing later, but no one seems to be using that ability. Inside Mac appears indecisive about printing, saying that printing spool files is done by the Printer utility, the code of which has apparently been integrated into the Finder. But Printer does exist as a seperate utility that will read a spool file, image it and print it. Since hardly any applications leave the spool file lying around, there hasen't been much opportunity to use the Printer utility.

Print Manager Calls: Lisa Pascal to Mac Pascal

In the printing chapter of Inside Mac a lengthy list of data types is presented along with 14 Pascal procedures and functions. This is the printing interface, but it is not made clear exactly where these procedures are found. The idea is that you are supposed to simply include the declarations and calls in your program and then link with a printing module. What is misleading about this is that the link is not with the procedures you think you are using but merely a piece of "glue". The actual code used to drive the printer is in the file 'Imagewriter' (usually in the system folder). Naturally, the code is in resources.

Imagewriter

To get a handle (pun intended) on printing, I examined the link module provided by Owen Densmore. I then duplicated Owen's algorithms in Pascal. You can find my versions of all 14 procedures in the following program.

The first task is to open a resource file. I said a bit on resources last month and there is never enough I can say about them. You should take a look in 'Imagewriter' and see what is there. The resources of interest here are of TYPE PDEF. These resources are actual printer-specific code. The code we need is in PDEF#0, PDEF#1, PDEF#4, and PDEF#5. In 'Imagewriter' is also a driver DRVR#-8192 named, '.print', but the one actually used is installed in the file, 'system'. The other stuff is for support of the dialog boxes the print manager presents. Rather than simply OpenResFile('Imagewriter');, we must take into account the possibility that there is more than one printer. To this end there is a resource STR #-8192 which contains the name of the print resource file. Therefore the print procedure PrOpen is ResID := OpenResFile( GetString(-8192) ); along with PBOpen of '.Print'. PrClose is simply CloseResFile(ResID). The other print procedures are in the PDEF resources and begin at various offsets into those resources.

The function GetAddress is used in the program to load one of the PDEF's (GetResource) and then to lock it in place (Hlock). It is then dereferenced and the offset is added. Once we have an absolute address to use we need a way to pass control to it. To do this I created the array jsr[0..3] of integer which contains code to JSR to the address on the top of the stack. Once again I take advantage of the fact that InlineP leaves register A0 pointing 2 bytes behind of the place we must return to. If you know no 68000 assembly you can ignore this.

The final detail to emulating the print interface code is that some of the routines release the PDEF handle and others leave it locked in place. This is the purpose of ReleaseAddress. Further, note that some of the routines use different PDEF's (0,1,2 or 3) depending on the setting of bjDocLoop. This is the purpose of MethodAdd. I find this a rather obscure feature and it will not be used here; nonetheless, the interface presented is complete, I think.

GrafPorts for Printing

It is necessary to use the type declarations to print but it is not necessary to closely study their form or function. I suggest studying my print record declarations in the program below along side "Printing Resources" in the new telephone version of Inside macintosh, where the print data structures are explained. A print record is created and filled in by the Printing Manager and the print dialog boxes. The printing port is set by a variant record type so that your program can write into the port as if it were a regular grafport, while the Printing Manager can modify the grafport for the printer.

The central issue is one of drawing in a GrafPort. Essentially, printing is no different than updating the contents of a window except that the size of the window is huge. To simply print a picture use a sequence like PrOpen, PrintDefault, PrOpenDoc, PrOpenPage, draw your picture, PrClosePage, PrCloseDoc, PrPicFile, and PrClose. To print more pages repeat PrOpenPage, draw, PrClosePage. Note the perfect symmetry with the exception of PrintDefault and PrPicFile. PrintDefault will fill in all those nasty hPrint fields for you and PrPicFile actually drives the printer. You may also modify your hPrint with PrStlDialog and PrJobDialog. These two present very familiar dialog boxes.

In the following program the procedure DrawPic draws a large picture in whatever port is current. In the main body of the program DrawPic is called several times to demonstrate the use of SetOrgin to show different views of the big picture. Of course, the parts of the picture that don't fit are chopped off by quickdraw and the same will happen when we print. I have found some strange complications. When printing, the VisRgn of the print port is not used, rather the clipRgn is used to delineate the usable area. In contrast, the drawing example opens up the ClipRgn and the VisRgn presents the limits. To investigate put:

with MyPort^.VisRgn^^.rgnBBox do writeln(top,left,bottom,right);  

in various places.

If you are doing a picture that is larger than one page don't assume the size of the page. You won't have to mess around in the grafport because you can use the rectangle hPrint^^.prInfoPt.Rpage to obtain the necessary offsets. Rpage.top and Rpage.left are zero so use right and bottom. I think this is the only one of the many hPrint fields that is commonly useful.

To make a banner, as promised, you will need the newer version of Imagewriter (sometimes called Imagewriter 15) or else there will be breaks between the pages. For banner format choose 'wide' and 'no breaks between pages' on the style dialog. You can change DrawPic to make any picture you please.

If there is any, and I mean any, subject that you think needs to be covered, write to me care of MacTutor and I will give it a try. I figure that if we can print with MacPascal then MacPascal can do just about anything.

program Banner_Print;{ by Alan Wootton 5/85 }
{ Prints a test pattern using the Printing Manager }

 uses
  Quickdraw2;
 type
  ptr = ^integer;
  handle = ^ptr;
  ProcPtr = ^longint;
  OStype = longint;

  strptr = ^str255;
  strHan = ^strptr;

{~~~~~~~~~ Print Manager Data Types ~~~~~~~~~~ }
{ note: byte size fields don't work right in MacPascal }

  TPStr80 = ^TStr80;
  TStr80 = string[80];

  TPRect = ^Rect;

  TPPrPort = ^TPrPort;
  TPrPort = record
    gPort : GrafPort                            ;{ GrafPort to draw in 
}
    gProcs : QDProcs      ;{ pointers to drawing routines }
    LGParam1, LGParam2 : longint;
    LGParam3, LGParam4 : longint;        { internal use }
    {         fOurPtr:boolean }
    fOurBits : integer;                       { boolean }
   end;

  TPPort = record
    case integer of
     0 : (
       pGPort : GrafPtr
     );
     1 : (
       pPrPort : TPPrPort
     )
   end;

  TPrInfo = record
    iDev : INTEGER;                   {driver information}
    iVRes : INTEGER;             {printer vertical resolution}
    iHRes : INTEGER;             {printer horizontal resolution}
    rPage : Rect                         {page rectangle}
   end;

  TPrStl = record
    wDev : integer;                    {  TWord;  used internally}
    iPageV : INTEGER;           {paper height}
    iPageH : INTEGER;          {paper width}
{          bPort : SignedByte;  printer or modem port}
    Tfeed : integer;                   { TFeed;   paper type}
   end;

  TFeed = (feedCut, {hand-fed, individually cut sheets}
   feedFanfold,        {continuous-feed fanfold paper}
   feedMechCut,      {mechanically fed cut sheets}
   feedOther);         {other types of paper}

  TPrJob = record
    iFstPage : INTEGER;         {first page to print}
    iLstPage : INTEGER;         {last page to print}
    iCopies : INTEGER;            {number of copies}
    bJDocLoop : integer;
{  printing method (in upper byte)  }
{         fFromUsr :  BOOLEAN;  }
{ TRUE if called from application }
    pIdleProc : ProcPtr; {background procedure}
    pFileName : TPStr80; {spool file name}
    iFileVol : INTEGER; {volume reference number}
{         bFileVers : SignedByte;  }
{         version number of spool file }
    bJobX : integer;{ SignedByte  not used}
   end;

  TScan = (scanTB,   {scan top to bottom}
   scanBT,   {scan bottom to top}
   scanLR,    {scan left to right}
   scanRL);  {scan right to left}

  TPrXInfo = record
    iRowBytes : INTEGER; {bytes per row}
    iBandV : INTEGER; {vertical dots}
    iBandH : INTEGER; {horizontal dots}
    iDevBytes : INTEGER; {size of bit image}
    iBands : INTEGER; {bands per page}
{         bPatScale : SignedByte;  used by Quickdraw}
    bUlThick : integer;
{        was Signed Byte,  underline thickness}
{         bUlOffset : Signed Byte;  underline offset}
    bUlShadow : integer;
{        was SignedByte, underline descender}
    scan : integer;{ TScan(byte), scan direction }
{         bXInfoX : SignedByte  not used }
   end;

  THPrint = ^TPPrint;
  TPPrint = ^TPrint;
  TPrint = record
    iPrVersion : INTEGER; {Printing Manager version}
    prInfo : TPrInfo; {printer information}
    rPaper : Rect; {paper rectangle}
    prStl : TPrStl; {style information}
    prInfoPT : TPrInfo; {Pcopy of PrInfo}
    prXInfo : TPrXInfo; {band information}
    prJob : TPrJob; {job information}
    printX : array[1..19] of INTEGER
{ printX used internally by print manager}
   end;

  TPrStatus = record
    iTotPages : INTEGER; {total number of pages}
    iCurPage : INTEGER; {page being printed}
    iTotCopies : INTEGER; {number of copies}
    iCurCopy : INTEGER; {copy being printed}
    iTotBands : INTEGER; {bands per page}
    iCutBand : INTEGER; {band being printed}
{         fPgDirty : BOOLEAN; in lower byte of iCutBand }
{         dirty is TRUE if started printing page}
    fImaging : integer;{ BOOLEAN;  TRUE if imaging}
    hPrint : THPrint; {print record}
    pPrPort : TPPrPort; {printing port}
    hPic : PicHandle {used internally}
   end;


{ Parameter Block information contained in File Manager}
{ chapter of Inside Macintosh.  Note that MacPascal }
{ won 't do 8 bit fields right.  We will only use the }
{ ioParam part here }

  ParamBlkPtr = ^ParamBlockRec;
  ParamBlockRec = record
    qLink : Ptr;
    qType : integer;
    ioTrap : integer;
    ioCmdAddr : ptr;
    ioCompletion : ptr;
    ioResult : integer;
    ioNamePtr : ^str255;
    ioVrefNum : integer;
{  case ParamBlkType of  ...  ioParam:  }
    ioRefNum : integer;
  {       ioVersNum : byte;  }
    ioPermssn : integer;{ byte }
    ioMisc : ptr;
    ioBuffer : ptr;
    ioReqCount : longint;
    ioActCount : longint;
    ioPosMode : integer;
    ioPosOffset : longint;
   end;

 var  {-----------global variables-----------}
{ jsr and access are 68000 glue routines }
{ jsr source code described below }
{ See MacTutor vol.1 no.6 for access source code }
  jsr : array[0..3] of integer;
  access : array[0..12] of integer;
  ResId : integer;{ id of currently open Printer file }
  hPrint : THPrint;{ data record for print job }
  pPrPort : TPPrPort;{ pointer to port to draw into }
  PrStatus : TPrStatus;{ printing status record }
  page : integer;{ page number currently printing }
  pageR : rect;{ copy of rPaper rectangle }
  width : integer;{ width of paper }
  maxR : rect;{ huge rectangle }
  myport : GrafPtr;{ for temporary use }


{           %%%    %%%        %%          %%                     }
{           %   %    %   %     %      %    %      %                  
}
{           %%%    %%%     %      %    %                           }
{           %          % %       %      %    %      %                
  }
{           %          %   %        %%          %%                   
  }
{----------beginning of procedure definitions----------}

{ This loads, locks, dereferences, and computes an }
{ entry point for a resource that will be used as code }
 function GetAddress (id, offset : integer) : longint;
  var
   h, d : Handle;
 begin
  h := pointer(LinlineF($A9A0, $50444546, id));
{ _GetResource('PDEF',id) }
  d := nil;
  inlineP($4E75, @d, @H, $A029, @access);
{ _Hlock( H ) }
  if d <> nil then
   writeln('GetAddress error', ord(d));
  GetAddress := ord(h^) + offset;
 end;

{ This unlocks a PDEF resource that was locked to run }
 procedure ReleaseAddress (id : integer);
  var
   h, d : Handle;
 begin
  h := pointer(LinlineF($A9A0, $50444546, id));
{ _GetResource('PDEF',id) }
  d := nil;
  inlineP($4E75, @d, @H, $A02A, @access);
{ _Hunlock( H ) }
  if d <> nil then
   writeln('ReleaseAddress error', ord(d));
 end;

{ this calls GetAddress for the appropriate resource. }
{ Which resource is used depends upon bjDocLoop. }
 function MethodAdd (hPrint : THPrint;
         offset : integer) : longint;
  var
   method : integer;
 begin
  method := hPrint^^.prJob.bjDocLoop div 256;
  method := method mod 4;
  hPrint^^.prJob.bjDocLoop := method * 256;
{    bjDocLoop is in upper byte.  It must be mod 4 }
  MethodAdd := GetAddress(method, offset);
 end;

{common OS trap code, could be done with 'Generic' call}
{ see MacTutor vol.1 no.6 for source code }
 function filecall (Pb : ParamBlkPtr;
         trap : integer) : integer;
  var
   d0, a0 : longint;
 begin
  a0 := ord(pb);
  inlineP($4E75, @d0, @a0, trap, @access);
{ $4E75 is rts to access routine }
  filecall := loword(d0);
 end;

{ The following File Manager calls work just like   }
{ those described in Inside Macintosh for the Lisa Pascal }
{ Workshop, except that the async parameter is a }
{ dummy; all calls are sync. }

 function PBOpen (Pb : ParamBlkPtr;
         async : boolean) : integer;
 begin
  PBOpen := filecall(pb, $A000);
 end;

{ Below are the Printing Manager calls. }
{ They are supposed to work just like the real ones. }

 procedure PrOpen;
  var
   sH : strHan;
   pblock : ParamBlockRec;
   Tstr : str255;
 begin
  Tstr := '.Print';
  pBlock.ioNamePtr := @Tstr; { first we open driver...}
  pBlock.ioPermssn := 0;
  if PBOpen(@pBlock, false) <> 0 then
   sysbeep(100);
{...then we open the resource fork of current printer file}
  sH := pointer(LinlineF($A9BA, $E000));
{ _GetString(-8192 ) = name of print manager }
  ResId := WinlineF($A997, sH^);
{ _OpenResFile of print manager, usually='Imagewriter'}
 end;

 procedure PrClose;
 begin
  inlineP($A99A, ResId);{ _CloseResFile }
{    note that the driver is left open }
 end;


 procedure PrintDefault (hPrint : THPrint);
 begin
  inlineP($4E75, hPrint, Getaddress(4, 0), @jsr);
{ $4E75 is rts to 'jsr' routine which runs  }
{ PDEF #4 with offset of zero. }
{ This same sequence is used below also }
  ReleaseAddress(4);
 end;

 function PrValidate (hPrint : THPrint) : boolean;
 begin
  PrValidate := 
          BinlineF($4E75, hPrint, Getaddress(4, 24), @jsr);
  ReleaseAddress(4);
 end;

 function PrStlDialog (hPrint : THPrint) : boolean;
 begin
  PrStlDialog := 
            BinlineF($4E75, hPrint, Getaddress(4, 4), @jsr);
  ReleaseAddress(4);
 end;

 function PrJobDialog (hPrint : THPrint) : boolean;
 begin
  PrJobDialog := 
            BinlineF($4E75, hPrint, Getaddress(4, 8), @jsr);
  ReleaseAddress(4);
 end;

 procedure PrJobmerge (hPrintSrc, hPrintDst :       
                                                    THPrint);
 begin
  inlineP($4E75, hPrintSrc, hPrintDst, 
                                              Getaddress(4, 28), @jsr);
  ReleaseAddress(4);
 end;

 function PrOpenDoc (hPrint : THPrint;
         pPrPort : TPPrPort;
         pIOBuf : Ptr) : TPPrPort;
  var
   lll : longint;
 begin
  lll := LinlineF($4E75, hPrint, pPrPort, pIOBuf,
                                         MethodAdd(hPrint, 0), @jsr);
  PROpenDoc := pointer(lll);
 end;

 procedure PrOpenPage (pPrPort : TPPrPort;
         pPageFrame : TPRect);
 begin
  inlineP($4E75, pPrPort, pPageFrame, 
                                         MethodAdd(hPrint, 8), @jsr);
 end;

 procedure PrClosePage (pPrPort : TPPrPort);
 begin
  inlineP($4E75, pPrPort, MethodAdd(hPrint, 12), @jsr);
 end;

 procedure PrCloseDoc (pPrPort : TPPrPort);
 begin
  inlineP($4E75, pPrPort, MethodAdd(hPrint, 4), @jsr);
  ReleaseAddress(1);
 end;

 procedure PrPicFile (hPrint : THPrint;
         pPrPort : TPPrPort;
         pIOBuff : Ptr;
         pDevBuf : Ptr;
         var prStatus : TPrStatus);
 begin
  inlineP($4E75, hPrint, pPrPort, pIOBuff, pDevBuf, 
                              @prStatus, Getaddress(5, 0), @jsr);
  ReleaseAddress(5);
 end;

 function PrError : integer;
  var
   eptr : Ptr;
 begin
  eptr := pointer($944);
  PrError := eptr^;
 end;

 procedure PrSetError (iErr : integer);
  var
   eptr : Ptr;
 begin
  eptr := pointer($944);
  eptr^ := iErr;
 end;


{ This is my routine to draw a sample picture. }
{ The picture is drawn into the current port. }
{ Note that this is a very wide picture. }
 procedure drawpic;
  var
   i : integer;
   r : Rect;
 begin
  moveto(4, 220);
  textfont(2);
  textsize(216);{ must be less than 256 }
  textface([bold, outline, underline]);
  drawstring('Hooray for MacTutor!');
 end;

                           %%%%%%%                               }
{                                 %%%                                
     }
{                                    %                               
         }
{                 Main entry point of program                    }
begin  
 stuffHex(@jsr, '5488225F2F084ED1');
{ Code to jsr to address on top of stack: }

{ 5488  addq.l   #2,a0      ;a0 is now return address }
{ 225F  move.l  (a7)+,a1  ;a1 is address of routine }
{ 2F08  move.l  a0,-(sp)   ;put return on stack }
{ 4ED1  jmp       (a1)         ;and call routine }

 stuffHex(@access, '2848548C41FA000C309F245F265F20522013FFFF224826804ED4');
{ access calls a register based trap }

 showdrawing;{ Set current port to Drawing window. }
 setrect(maxR, 10, 100, 510, 330);
 SetDrawingRect(maxR);{ Make Drawing big. }
 setrect(maxR, -32000, -32000, 32000, 32000);
{  make maxR huge }

 cliprect(maxR); { Open up clip region. }
 for page := 0 to 8 do{ Draw 9 times for preview. }
  begin
   setOrigin(page * 300, 0);{ Use increasing offset. }
   eraserect(maxR);
   drawpic;{<------ Draw our picture in drawing. }
  end;

 hPrint := NewHandle(120);
{ 120 is size of TPrint record. }

 PrOpen;{ Open Printing Manager. }

 PrintDefault(hPrint);{ Fetch default hPrint. }

{ Now modify style info of hPrint if desired. }
{ For banner chose Wide and No Breaks Between Pages. }
 if PrStlDialog(hPrint) then
  writeln('new style chosen');

{ Then get job info for hPrint. }
 if PrJobDialog(hPrint) then
  begin
   pPrPort := PrOpenDoc(hPrint, nil, nil);
{ Grafport is now pPrPort, not Drawing window. }

   pageR := hPrint^^.prInfoPt.Rpage;
   pageR.right := pageR.right div 2;
   pageR.bottom := pageR.bottom div 2;
   width := pageR.right;{ width of printing 'window' }
{ Draw into rect 1/2 page size, quickdraw will }
{ scale picture to fit page later. This effectivly doubles}
{ the size of our drawing. }

{ Now we will draw the picture. It will go into pPrPort. }
{ For each page we offset to clip off parts not used. }
   getport(myport);{ myport := pPrPort; }
   for page := 0 to 7 do{ 8 pages }
    begin
     PrOpenPage(pPrPort, @pageR);
{ PrOpenPage resets the ports size, coordinates etc. }

     setOrigin(width * page, 0);

{ setOrigin does not change cliprgn so we do it here. }
     offsetRgn(myport^.cliprgn, width * page, 0);
{ I tried simply maxing out the clip and it didn't work. }

     drawpic;{<---------draw picture into pPrPort}

     PrClosePage(pPrPort);
    end;

   PrCloseDoc(pPrPort);

   PrPicFile(hPrint, nil, nil, nil, PrStatus);
  end;{ if job }

 disposeHandle(hPrint);
 PrClose;
end.
 

Community Search:
MacTech Search:

Software Updates via MacUpdate

Capto 1.2.9 - $29.99
Capto (was Voila) is an easy-to-use app that takes capturing, recording, video and image editing to the next level. With an intelligent file manager and quick sharing options, Capto is perfect for... Read more
Opera 51.0.2830.40 - High-performance We...
Opera is a fast and secure browser trusted by millions of users. With the intuitive interface, Speed Dial and visual bookmarks for organizing favorite sites, news feature with fresh, relevant content... Read more
GarageSale 7.0.13 - Create outstanding e...
GarageSale is a slick, full-featured client application for the eBay online auction system. Create and manage your auctions with ease. With GarageSale, you can create, edit, track, and manage... Read more
1Password 6.8.7 - Powerful password mana...
1Password is a password manager that uniquely brings you both security and convenience. It is the only program that provides anti-phishing protection and goes beyond password management by adding Web... Read more
Evernote 7.0.1 - Create searchable notes...
Evernote allows you to easily capture information in any environment using whatever device or platform you find most convenient, and makes this information accessible and searchable at anytime, from... Read more
MacUpdate Desktop 6.2.0 - $20.00
MacUpdate Desktop brings seamless 1-click app installs and version updates to your Mac. With a free MacUpdate account and MacUpdate Desktop 6, Mac users can now install almost any Mac app on... Read more
HoudahSpot 4.3.5 - Advanced file-search...
HoudahSpot is a versatile desktop search tool. Use HoudahSpot to locate hard-to-find files and keep frequently used files within reach. HoudahSpot will immediately feel familiar. It works just the... Read more
EtreCheck 4.0.4 - For troubleshooting yo...
EtreCheck is an app that displays the important details of your system configuration and allow you to copy that information to the Clipboard. It is meant to be used with Apple Support Communities to... Read more
WhatsApp 0.2.8361 - Desktop client for W...
WhatsApp is the desktop client for WhatsApp Messenger, a cross-platform mobile messaging app which allows you to exchange messages without having to pay for SMS. WhatsApp Messenger is available for... Read more
iClock 4.2 - Customize your menubar cloc...
iClock is a menu-bar replacement for Apple's default clock but with 100x features. Have your Apple or Google calendar in the menubar. Have the day, date, and time in different fonts and colors in the... Read more

Latest Forum Discussions

See All

The best games like Florence
Florence is a great little game about relationships that we absolutely adored. The only problem with it is it's over a little too soon. If you want some other games with some emotional range like Florence, check out these suggestions: [Read more] | Read more »
Angry Birds Champions adds cash prizes t...
Collaborating with developer Rovio Entertainment, GSN Games has released a twist on the Angry Birds formula. Angry Birds Champions features the same bird-flinging gameplay, but now you can catapult Red and co for cash. | Read more »
Around the Empire: What have you missed...
148Apps is part of a family. A big family of sites that make sure you're always up to date with all the portable gaming news. Just like a real family, I guess. I don't know, my mum never told me anything about Candy Crush to be fair. [Read more] | Read more »
The Battle of Polytopia Guide - Tips for...
The addition of multiplayer to The Battle of Polytopia has catapulted the game from a fun enough time waster to a fully-fledged 4X experience on your phone. We've been playing quite a few matches over the past week or so, and we've put together a... | Read more »
All the best games on sale for iPhone an...
Hi there, and welcome to our round up of all the best games that are on sale for iOS at the moment. It's not a vintage week in terms of numbers, but I'm pretty sure that every single one of these is worth picking up if you haven't already played... | Read more »
Disc Drivin' 2 Guide - Tips for the...
We're all still playing quite a bit of Disc Drivin' 2 over here at 148Apps, and we've gotten pretty good at it. Now that we've spent some more time with the game and unlocked more powerups, check out some of these more advanced tips: | Read more »
Alto's Odyssey Guide - How to Tackl...
Alto’s Odyssey is a completely stunning and serene runner, but it can also be a bit tricky. Check out these to try and keep your cool while playing this endless runner: Don’t focus too much on tasks [Read more] | Read more »
Here's everything you need to know...
Alto's Odyssey is a really, really good game. If you don't believe me, you should definitely check out our review by clicking this link right here. It takes the ideas from the original Alto's Adventure, then subtly builds on them, creating... | Read more »
Alto's Odyssey (Games)
Alto's Odyssey 1.0.1 Device: iOS Universal Category: Games Price: $4.99, Version: 1.0.1 (iTunes) Description: Just beyond the horizon sits a majestic desert, vast and unexplored. Join Alto and his friends and set off on an endless... | Read more »
Vainglory 5v5: Everything you need to kn...
Vainglory just got bigger. [Read more] | Read more »

Price Scanner via MacPrices.net

Use your Apple Education discount and save up...
Purchase a new Mac using Apple’s Education discount, and take up to $400 off MSRP. All teachers, students, and staff of any educational institution with a .edu email address qualify for the discount... Read more
Apple Canada offers 2017 21″ and 27″ iMacs fo...
 Canadian shoppers can save up to $470 on the purchase of a 2017 current-generation 21″ or 27″ iMac with Certified Refurbished models at Apple Canada. Apple’s refurbished prices are the lowest... Read more
9″ iPads available online at Walmart for $50...
Walmart has 9.7″ Apple iPads on sale for $50 off MSRP for a limited time. Sale prices are for online orders only, in-store prices may vary: – 9″ 32GB iPad: $279.99 $50 off – 9″ 128GB iPad: $379.99 $... Read more
15″ Apple MacBook Pros, Certified Refurbished...
Save $360-$420 on the purchase of a 2017 15″ MacBook Pro with Certified Refurbished models at Apple. Apple’s refurbished prices are the lowest available for each model from any reseller. An standard... Read more
Amazon restocks MacBook Pros with models avai...
Amazon has restocked 15″ and 13″ Apple MacBook Pros with models on sale for up to $251 off MSRP. Shipping is free. Note that stock of some Macs may come and go (and some sell out quickly), so check... Read more
Lowest price of the year: 15″ 2.8GHz Apple Ma...
Amazon has the 2017 Space Gray 15″ 2.8GHz MacBook Pro on sale today for $251 off MSRP. Shipping is free: – 15″ 2.8GHz Touch Bar MacBook Pro Space Gray (MPTR2LL/A): $2148, $251 off MSRP Their price is... Read more
Apple restocks full line of Certified Refurbi...
Apple has restocked a full line of Apple Certified Refurbished 2017 13″ MacBook Pros for $200-$300 off MSRP. A standard Apple one-year warranty is included with each MacBook, and shipping is free.... Read more
Lowest sale price available for 13″ 1.8GHz Ma...
Focus Camera has the 2017 13″ 1.8GHz/128GB Apple MacBook Air on sale today for $829 including free shipping. Their price is $170 off MSRP, and it’s the lowest price available for a current 13″... Read more
21-inch 2.3GHz iMac on sale for $999, $100 of...
B&H Photo has the 2017 21″ 2.3GHz iMac (MMQA2LL/A) in stock and on sale for $999 including free shipping plus NY & NJ tax only. Their price is $100 off MSRP. Read more
Apple refurbished Mac minis in stock again st...
Apple has restocked Certified Refurbished Mac minis starting at $419. Apple’s one-year warranty is included with each mini, and shipping is free: – 1.4GHz Mac mini: $419 $80 off MSRP – 2.6GHz Mac... Read more

Jobs Board

*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description:SalesSpecialist - Retail Customer Service and SalesTransform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description: Sales Specialist - Retail Customer Service and Sales Transform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
*Apple* Solutions Consultant - Apple (United...
# Apple Solutions Consultant Job Number: 113523441 Orange, CA, California, United States Posted: 21-Feb-2018 Weekly Hours: 40.00 **Job Summary** Are you passionate Read more
*Apple* Retail - Multiple Positions - Apple,...
Job Description:SalesSpecialist - Retail Customer Service and SalesTransform Apple Store visitors into loyal Apple customers. When customers enter the store, Read more
All contents are Copyright 1984-2011 by Xplain Corporation. All rights reserved. Theme designed by Icreon.